xHarbour Reference Documentation > Function Reference

OrdSkipRaw()

Moves the record pointer via the controlling index.

Syntax

OrdSkipRaw( [<nRecords>] ) --> NIL

Arguments

<nRecords>

This is a numeric value indicating the number of records to move the record pointer within the controlling index. Positive values for <nRecords> move the record pointer forwards (towards the last logical record), negative values move it backwards. The default value is 1, i.e. calling OrdSkipRaw() with no parameter advances the record pointer to the next logical record.

Return

The return value is always NIL.

Description

OrdSkipRaw() moves the record pointer using information from the controlling index only, and ignores any filter condition set with SET DELETED or SET FILTER. All records included in the controlling index can be navigated to with OrdSkipRaw().

Use function DbSkip() when a filter condition should be recognized for record pointer movement.

Info

See also:	DbSkip(), DbOrderInfo(), OrdKeyCount(), OrdKeyGoTo(), OrdScope(), Recno()
Category:	Database functions , Index functions , xHarbour extensions
Source:	rdd\dbcmd.c
LIB:	xhb.lib
DLL:	xhbdll.dll

Example

// The example demonstrates movement of the record pointer using
// DbSkip() versus OrdSkipRaw(). Note that Bof() returns  .F.
// with OrdSkipRaw() although the filter condition is not met.

   PROCEDURE Main
      USE Customer
      INDEX ON Upper(LastName) TO Cust01

      ? Bof(), Lastname     // result:  .F.  Alberts

      SET FILTER TO Lastname >= "K"

      GO TOP
      ? Bof(), Lastname     // result:  .F.  Keller

      DbSkip( -1 )
      ? Bof(), Lastname     // result:  .T.  Keller

      OrdSkipRaw( -1 )
      ? Bof(), Lastname     // result:  .F.  Henreid

      USE
   RETURN