xHarbour Reference Documentation > Function Reference

MlPos()

Determines the starting position of a line in a formatted character string or memo field.

Syntax

MlPos( <cString>   , ;
      [<nLineLen>  , ;
      [<nLineNum>] , ;
      [<nTabSize>] , ;
      [<lWrap>]    , ;
      [<lLongLines>] ) --> nPosition

Arguments

<cString>

A character string or memo field to scan. It can be a formatted text string that includes Tab and Hard/Soft carriage return characters.

<nLineLen>

A numeric value specifying the number of characters per text line. It is usually a value between 4 and 254. If <nLineLen> is larger than 254 characters, parameter <lLongLines> must be set to .T. (true). The default value for <nLineLen> is 79.

<nLineNum>

A numeric value specifying the text row, or line number, to find the starting position for. Text lines are counted beginning with 1, which is also the default value for <nLineNum>.

<nTabSize>

A numeric value specifying the number of blank spaces the Tab character should be expanded to. It defaults to 4 blank spaces.

<lWrap>

A logical value indicating if word wrapping should be applied to <cString> when lines are scanned. The default value is .T. (true), resulting in text lines that contain whole words only. When a word does not fit entirely to the end of the scanned text line, it is wrapped to the next text line. Passing .F. (false) for this parameter turns word wrapping off so that only lines ending with a hard carriage return are scanned.

<lLongLines>

This parameter defaults to .F. (false). It must be set to .T. (true) when text lines of more than 254 characters should be scanned.

Return

The function returns the starting position of the text line having number <nLineNum> in <cString>. Position counting starts with 1.

Description

MLPos() is used similar to MLCToPos() for finding an exact byte position in a formatted text string. MlPos() ingnores column positions within a text line and searches only for the beginning of a line of text.

Info

See also:	MemoLine(), MemoTran(), MLCount(), MLCToPos(), MPosToLC()
Category:	Character functions , Memo functions
Source:	rtl\mlpos.c
LIB:	xhb.lib
DLL:	xhbdll.dll

Example

// This example determines the starting position of the 4th line
// when the text string is formatted with 10 characters per line:

   PROCEDURE Main
      LOCAL cString  := "The quick brown fox jumps over the lazy dog"
      LOCAL cLine    := ""
      LOCAL nLineLen := 10
      LOCAL i, imax  := MLCount( cString, nLineLen )

      ? '"' + cString + '"'
      ?
      FOR i:=1 TO imax
         cLine := MemoLine( cString, nLineLen, i )
         ? '"' + cLine + '"'
      NEXT
      // Output so far:
      // "The quick brown fox jumps over the lazy dog"
      //
      // "The quick "
      // "brown fox "
      // "jumps over"
      // "the lazy  "
      // "dog       "
      ?
      ? i := MLPos( cString, nLineLen, 4 )   // result: 32
      ? SubStr( cString, i, nLineLen )       // result: the lazy d
   RETURN