xHarbour Reference Documentation > Preprocessor Reference

#xuncommand | #xuntranslate

Voids a previously defined #xcommand or #xtranslate directive.

Syntax

#xuncommand    <searchPattern>
#xuntranslate  <searchPattern>

Arguments

<searchPattern>

This is the definition of the search pattern of a previously defined #xcommand or #xtranslate directive. The search pattern must be specified in the same manner as used in the definition of the #xcommand or #xtranslate directive to remove.

Description

The directives #xuncommand and #xuntranslate remove a previously defined #xcommand or #xtranslate directive. The removed translation rule becomes unavailable and can be redefined.

#xuncommand/#xuntranslate match the entire translation rule previously defined with #xcommand or #xtranslate. The similar to #uncommand/#untranslate directives, in contrast, match only the first keyword in the corresponding #command or #translate directive.

Info

See also:	#command | #translate, #uncommand | #untranslate
Category:	Preprocessor directives , xHarbour extensions

Example

// The example demonstrates the effect of removing a translation rule.

   #xcommand  COMMAND  <x>           =>  A_Command( <x> )
   #xcommand  COMMAND  <x> WITH <y>  =>  B_Command( <x>, <y> )

   PROCEDURE Main
                                     **  PPO file:
      COMMAND x                      //  A_Command(x )
      COMMAND x WITH y               //  B_Command(x,y )

      #xuncommand COMMAND <x>

      COMMAND x                      //  COMMAND x
      COMMAND x WITH y               //  B_Command(x,y )

   RETURN