xHarbour Reference Documentation > Statement Reference

ANNOUNCE

Declaration of a module identifier name.

Syntax

ANNOUNCE <ModuleId>

Arguments

<ModuleId>

<ModuleId> is the symbolic name of a module.

Description

The ANNOUNCE statement declares a symbolic name for the linker which is not declared as FUNCTION, PROCEDURE or CLASS in the PRG code of an xHarbour project. This way, an entire module can be assigned a symbolic name that is later resolved by the linker.

ANNOUNCE must appear prior to any executable statement in a PRG source code file. The <ModuleID> identifier must be unique for the entire xHarbour project.

Info

See also:	#include, EXTERNAL, REQUEST
Category:	Declaration , Statements

Examples

// The example shows how the default replaceable database driver
// is linked into an application.

   ANNOUNCE RDDSYS

   REQUEST _DBF
   REQUEST DBFNTX
   REQUEST DBFFPT

   PROCEDURE Main

      ? "This program has the default RDD linked in"

   RETURN

// The example demonstrates how to produce an executable that does not
// require/use a replaceable database driver.

   ANNOUNCE RDDSYS

   PROCEDURE Main

      ? "This program has no RDD linked in"

   RETURN