xHarbour Reference Documentation > Function Reference

DispOutAt()

Displays a value on the screen at a certain position.

Syntax

DispOutAt( <nRow>      , ;
           <nCol>      , ;
           <expression>, ;
           [<cColor>]  , ;
           [<lSetPos>]   ) --> NIL

Arguments

<nRow>

This is a numeric value specifying the row on the screen where the value of <expression> is displayed.

<nCol>

This is a numeric value specifying the column on the screen where the value of <expression> is displayed.

<expression>

Any expression whose value should be output to the screen.

<cColor>

An optional SetColor() compliant color string can be specified for display. It defaults to the standard color of SetColor().

<lSetPos>

An optional logical value specifies whether or not to update the screen cursor position after display. .T. (true) updates the cursor position and .F. (false) leaves the cursor position unchanged. The default is the return value of function DispOutAtSetPos().

Return

The return value is always NIL.

Description

The DispOutAt() function displays the value of <expression> at the specified cursor position on the screen, using the color <cColor>. The position of the screen cursor after display depends on parameter <lSetPos>.

Info

See also:	Col(), DispBegin(), DispCount(), DispEnd(), DispOut(), DispOutAtSetPos(), Row(), SetPos()
Category:	Output functions , Screen functions , xHarbour extensions
Source:	rtl\console.c
LIB:	xhb.lib
DLL:	xhbdll.dll

Example

// The example uses background processing for displaying the time
// continuously without changing the cursor position while Browse()
// is active.

   PROCEDURE Main
      LOCAL nIdle, bTask, nTask

      SET BACKGROUND TASKS ON

      bTask := {|| DispoutAt( 0, MaxCol()-7, Time(), "W+/B", .F. ) }
      nTask := HB_BackGroundAdd( bTask, 1000 )
      nIdle := HB_IdleAdd( {|| HB_BackGroundRun() } )

      USE Customer
      Browse()
      USE

      HB_BackGroundDel( nTask )
      HB_IdleDel( nIdle )
   RETURN