xHarbour Reference Documentation > Command Reference

SET RELATION

Synchronizes the record pointers in one or more work areas.

Syntax

SET RELATION TO [<expression1>|<nRecord1> INTO <cAlias1> [SCOPED]] ;
         [, [TO] <expressionN>|<nRecordN> INTO <cAliasN> [SCOPED]]
         [ADDITIVE]

Arguments

TO <expression>

This is the expression used to relate the current work area with a secondary one. The current work area becomes the parent of the secondary, which is also referred to as child work area. The effect of such a relation is that the record pointer in the child work area is synchronized with the parent work area. The database in the child work area <cAlias> must have a controlling index whose index expression matches <expression>.

The record pointer in the child work area is synchronized using a SEEK operation. The value of <expression> is passed to SEEK.

When no argument is passed, all active relations in the current work area are cleared.

TO <nRecord>

This is a numeric expression. The record pointer in the child work area is synchronized either with a GOTO operation or with a SEEK operation. GOTO is used when there is no controlling index in the child work area. SEEK is used when the controllng index in the child work area is of numeric data type.

INTO <cAlias>

The parameter specifies the alias name of the child work area. It can be specified as a literal alias name, or a character expression enclosed in parentheses.

SCOPED

When the SCOPED option is used, database navigation in the child work area is restricted (scoped) to the records that relate to the current record in the parent work area.

ADDITIVE

This option is only meaningful when relations are already defined in the current work area. In this case, all relations remain active, and new ones are defined. If ADDITIVE is omitted, all existing relations are cleared prior to defining new ones.

When relating two work areas based on matching record numbers, use the Recno() function for the SET RELATION TO expression. Make sure that the child work area has no controlling index.

Info

See also:	DbClearRelation(), DbRelation(), DbRSelect(), DbSetRelation(), Found(), RecNo(), SET INDEX, SET ORDER, SET SOFTSEEK
Category:	Database commands
Source:	rdd\dbcmd.c
LIB:	xhb.lib
DLL:	xhbdll.dll

Example

// The example lists data from a customer and an invoice database

   PROCEDURE Main
      USE Customer ALIAS Cust

      USE Invoice  ALIA Inv NEW
      INDEX ON CustNo TO Invoice01

      SELECT Cust
      SET RELATION TO CustNo INTO Inv

      // Invoice data changes whith each SKIP in Customer database
      DO WHILE .NOT. Eof()
         ? Cust->LastName, Cust->FirstName, Inv->Total
         SKIP
      ENDDO

      CLOSE ALL
   RETURN