xHarbour Reference Documentation > Function Reference

RddList()

Retrieves information about available Replaceable Database Drivers (RDDs).

Syntax

RddList( [<nRddType>] ) --> aRDDNames

Arguments

<nRddType>

A numeric value indicating the type of RDDs to list names for. #define constants contained in RDDSYS.CH are used for this parameter.

Types of RDDs

Constant	Value	Description
RDT_FULL *)	1	RDDs with full functionality
RDT_TRANSFER	2	RDDs having only import/export capabilities
*) default

Return

The function returns a one-dimensional array whose elements contain the names of replaceable database drivers as character strings.

Description

RddList() is an informational RDD function used to obtain the names of RDDs available at runtime of an xHarbour application.

Info

See also:	RddInfo(), RddName(), RddSetDefault()
Category:	Database drivers
Header:	rddsys.ch
Source:	rdd\dbcmd.c
LIB:	xhb.lib
DLL:	xhbdll.dll

Example

// The example requests various RDDs to be linked and lists
// the RDD names.

   #include "RDDSYS.CH"

   REQUEST DBFCDX
   REQUEST SDF
   REQUEST DELIM

   PROCEDURE Main
      LOCAL aNames

      aNames := RddList( RDT_FULL )

      ? "RDT_FULL"
      AEval( aNames, {|c| Qout(c) } )

      aNames := RddList( RDT_TRANSFER )
      ?
      ? "RDT_TRANSFER"
      AEval( aNames, {|c| Qout(c) } )
   RETURN