xHarbour Reference Documentation > Command Reference

@...TO

Displays a single or double lined frame on the screen.

Syntax

@ <nTop>, <nLeft> TO <nBottom>, <nRight> ;
              [COLOR <cColor>] [DOUBLE]

Arguments

@ <nTop>, <nLeft>

Numeric values indicating the screen coordinates for the upper left corner of the frame to display.

TO <nBottom>, <nRight>

Numeric values indicating the screen coordinates for the lower right corner of the frame to display.

<cColor>

An optional SetColor() compliant color string can be specified to draw the frame. It defaults to the standard color of SetColor().

DOUBLE

This option displays the frame with a double line. If omitted, a single line is used.

Description

The @...TO command displays a frame on the screen using the standard color of SetColor() or <cColor>, if specified.

When the frame is completely drawn, the cursor is positioned at the coordinates <nTop>+1 and <nLeft>+1, so that Row() and Col() can be used to start displaying text in the upper left corner of the frame area.

Info

See also:	@...BOX, @...CLEAR, DispBox()
Category:	Output commands
Source:	rtl\box.c
LIB:	xhb.lib
DLL:	xhbdll.dll

Example

// The example displays two frames using different colors and
// borders.

   PROCEDURE Main
      CLS
      @ 10, 5 TO 20, 35 COLOR "W+/B"
      @ Row(), Col() SAY "Single"

      @ 10, 45 TO 20, 75 COLOR "N/BG" DOUBLE
      @ Row(), Col() SAY "Double"
   RETURN